*= $CC00
	;sys 52224
;v1.1
	JMP LOAD
;---------------------------------------
PORTD    = $DD03
PORT     = $DD01
BUFOR    = $1000
BUFOR1   = $2000
;---------------------------------------
OUT      = $02
BUFOUT   = $03
BUFIN    = $04
FUP      = $22
SUP      = $24
CMDBYTE  = $F7
LICZNIK  = $FE
;---------------------------------------
;POLECENIA
CMD17    ;BLOCKREAD
         .BYTE $51,$00,$04,$7E,$00,$FF
ADRES	 .BYTE $08,$0e
COUNT	 .BYTE $02
;---------------------------------------
INITCIA
         LDA PORTD
         AND #%11110000
         ORA #%00001110
         STA PORTD
         LDA PORT
         AND #%11110000
         ORA #%00001110
         STA OUT
;-----------
SETCLK1
         LDA OUT
         ORA #%00000100
         STA OUT
         STA PORT
         RTS
SETCLK0
         LDA OUT
         AND #%11111011
         STA OUT
         STA PORT
         RTS
;-----------
SETCS1
         LDA OUT
         ORA #%00001000
         STA OUT
         STA PORT
         RTS
SETCS0
         LDA OUT
         AND #%11110111
         STA OUT
         STA PORT
         RTS
;-----------
SPI
         STA BUFOUT

         LDX #8
SPI2
         CLC
         ASL BUFOUT
         BCC SPI3
         LDA OUT
         AND #%11111001
         ORA #%00000010
         BCS SPI4
SPI3     LDA OUT
         AND #%11111001
SPI4
         STA PORT
         LDA PORT
         ORA #%00000100
         STA OUT
         STA PORT

         ROR A
         ROL BUFIN

         DEX
         BNE SPI2
SPIEND
         LDA OUT
         ORA #2
         STA OUT
         STA PORT
         LDA BUFIN
         RTS
;-----------
SPIFR
         LDX #8
SPIFR2
         LDA OUT
         AND #%11111001
         ORA #%00000010
         STA PORT
         LDA PORT
         ORA #%00000100
         STA OUT
         STA PORT
         ROR A
         ROL BUFIN
         DEX
         BNE SPIFR2
         JMP SPIEND
;-----------
;LDY #>CMD
;LDA #<CMD
;JSR SETCMD
;
SETCMD
         STY FUP+1
         STA FUP
         LDY #0
SETCMD1
         LDA (FUP),Y
         STA CMDBYTE,Y
         INY
         CPY #6
         BNE SETCMD1
         RTS
;-----------
CMD
         JSR SETCS1

         LDA OUT
         AND #%11111101
         ORA #%00000010
         STA OUT
         STA PORT

         LDX #8
CMD0
         JSR SETCLK0
         JSR SETCLK1
         DEX
         BNE CMD0


         JSR SETCS0

         LDA CMDBYTE
         JSR SPI
         LDA CMDBYTE+1
         JSR SPI
         LDA CMDBYTE+2
         JSR SPI
         LDA CMDBYTE+3
         JSR SPI
         LDA CMDBYTE+4
         JSR SPI
         LDA CMDBYTE+5
         JSR SPI
CMD1
         JSR SPIFR
         CMP #$FF
         BEQ CMD1
         RTS
;-----------
MMCINIT
         JSR SETCS1

         LDY #0
MMCINIT1
         JSR SPIFR
         INY

         CPY #12
         BNE MMCINIT1
         JSR SETCS0

         LDA #$40
         STA CMDBYTE
         LDA #0
         STA CMDBYTE+1
         STA CMDBYTE+2
         STA CMDBYTE+3
         STA CMDBYTE+4
         LDA #$95
         STA CMDBYTE+5
         JSR CMD
         
         INC CMDBYTE
         LDA #$FF
         STA CMDBYTE+5
MMCINIT2
         JSR CMD
         CMP #0
         BNE MMCINIT2
         JMP SETCS1
;-----------
BLOCKRD
         JSR CMD
BLOCKRD1
         JSR SPIFR
         CMP #$FE
         BNE BLOCKRD1

         LDY #0
BLOCKRD2
         JSR SPIFR
         INC 1
         STA (FUP),Y
         DEC 1
         STA $D020
         INY
         BNE BLOCKRD2
         INC FUP+1
BLOCKRD3
         JSR SPIFR         
	INC 1
         STA (FUP),Y
         DEC 1
         STA $D020
         INY
         BNE BLOCKRD3
         JSR SPIFR
         JSR SPIFR
         JMP SPIFR
;---------------------------------------
SCROFF
         LDA $D011
         AND #%11101111
         STA $D011
         RTS
SCRON
         LDA $D011
         AND #%11101111
         ORA #%00010000
         STA $D011
         RTS
;---------------------------------------
LOAD
         SEI
         LDA #$37
         STA 1

         JSR SCROFF
         JSR INITCIA
         JSR MMCINIT

         LDY #>CMD17
         LDA #<CMD17
         JSR SETCMD

         LDY adres
         LDA adres+1
         STY FUP+1
         STA FUP

         LDA COUNT
         STA LICZNIK
LOAD1
         JSR BLOCKRD
         INC FUP+1
         INC CMDBYTE+3
         INC CMDBYTE+3
         BNE LOAD2
         INC CMDBYTE+2
LOAD2
         DEC LICZNIK
         LDA LICZNIK
         BNE LOAD1
         LDA #0
         STA $D020
         JSR SCRON
         CLI
         RTS